Перейти к содержанию

Сборка и развертывание с использованием CI/CD

Сборка и развертывание платформы iSpace

Для обеспечения стабильности, повторяемости и скорости доставки обновлений платформы iSpace, можно использовать практики непрерывной интеграции и доставки (CI/CD). Сборку Docker-образов фронтенд (Client) и бэкенд (Platform) частей приложения можно автоматизировать с помощью популярных инструментов, таких как Jenkins или GitLab CI/CD. Исходный код приложения хранится в системах контроля версий на базе Git (GitLab, Bitbucket, GitHub или корпоративный Git-сервер).

Подготовка CI/CD окружения

Перед запуском сборки в вашей CI/CD-системе необходимо настроить следующие параметры:

  • Учетные данные для доступа к Git-репозиторию (SSH-ключ или токен доступа).

  • Учетные данные для доступа к Docker Registry (логин и пароль для push-операций).

  • Токен для SonarQube (опционально, для статического анализа кода).

  • Все чувствительные данные должны храниться в защищенном хранилище секретов CI/CD-системы (например, Jenkins Credentials), а не в открытом виде в коде пайплайна.

Пример конфигурации Jenkins Pipeline

Ниже приведены шаблонные конфигурации Jenkins (скрипт Groovy) для фронтенд и бэкенд частей.

Warning

Перед использованием замените значения в угловых скобках ВАШЕ_ЗНАЧЕНИЕ на актуальные данные вашей инфраструктуры.

Шаблон пайплайна для Фронтенда (Client)

Note

Этот пайплайн собирает клиентскую часть приложения и публикует образ в реестр.

pipeline {
    agent any     
    environment {
        // Замените на ID учетных данных SonarQube, настроенных в Jenkins
        IMAGE_NAME = 'ispace.client'
    }    
    options {
        timestamps() // Добавляет временные метки в лог
    }    
    parameters {
        string(name: 'TAG', defaultValue: 'latest', description: 'Введите версию (TAG) для образа')
        choice(name: 'BRANCH', choices: ['develop', 'main', 'release/x.x.x'], description: 'Выберите целевую ветку для сборки')
        choice(name: 'NEXUS_REPO', choices: ['internal', 'public', 'docker-hub'], description: 'Выберите целевой репозиторий для публикации')
    }

    stages {

        stage('CleanUp') { 
            steps {
                echo "--- START CLEANUP STAGE ---" 
                cleanWs notFailBuild: true
                echo "--- END CLEANUP STAGE ---" 
            }
        }

        stage('Git Checkout') { 
            steps {
                echo "--- START GIT CHECKOUT ---"
                echo "Checking out branch: ${params.BRANCH}"
                checkout scm: [
                    $class: 'GitSCM', 
                    branches: [[name: "*/${params.BRANCH}"]], 
                    extensions: [], 
                    userRemoteConfigs: [[
                        // Замените на ID учетных данных Git и URL вашего репозитория
                        credentialsId: '<ВАШ_ID_УЧЕТНЫХ_ДАННЫХ_GIT>', 
                        url: 'https://<ВАШ_GIT_SERVER>/<ВАШ_ПРОЕКТ>/ispace.client.git'
                    ]]
                ]
                echo "--- END GIT CHECKOUT ---"
            }
        }

        stage('Build Docker Image') {
            steps {
                echo "--- START Docker build iSpace.Client ---"
                script {
                    def fullImageName = getImageName(params.NEXUS_REPO, env.IMAGE_NAME, params.TAG)
                    echo "Building image: ${fullImageName}"                    
                    docker.build("${fullImageName}", "-f Conteq.iSpace.Workspace/Dockerfile ./Conteq.iSpace.Workspace")                    
                }
                echo "--- END Docker build iSpace.Client ---"
            }
        }

        stage('Push to Selected Repository') {
            steps {
                echo "--- START Docker push to ${params.NEXUS_REPO} ---"
                script {
                    def fullImageName = getImageName(params.NEXUS_REPO, env.IMAGE_NAME, params.TAG)
                    def (registryUrl, credentialsId) = getRegistryConfig(params.NEXUS_REPO)

                    echo "Pushing to: ${registryUrl} using credentials: ${credentialsId}"

                    docker.withRegistry(registryUrl, credentialsId) {
                        def dockerImage = docker.image(fullImageName)
                        dockerImage.push()                     
                    }
                }
                echo "--- END Docker push ---"                
            }
        }
    }

    post {
        success {
            echo 'Pipeline completed successfully'
            // Здесь можно добавить шаг отправки уведомления в Telegram/Slack/Email
        }
        failure {
            echo 'Pipeline failed'
            mail to: '<ВАШ_EMAIL_ДЛЯ_УВЕДОМЛЕНИЙ>@company.com',
                subject: "Jenkins Pipeline Failed: ${env.JOB_NAME} ${env.BUILD_NUMBER}",
                body: "The build ${env.BUILD_NUMBER} of ${env.JOB_NAME} has failed. Please check Jenkins for more details."
        }
    }
}

// 📍 ВСПОМОГАТЕЛЬНЫЕ ФУНКЦИИ
def getImageName(repoType, baseImageName, tag) {
    def repositories = [
        'internal': '<ВАШ_REGISTRY_URL>/internal',
        'public': '<ВАШ_REGISTRY_URL>/public', 
        'docker-hub': '<ВАШ_DOCKERHUB_ORG>' 
    ]
    return "${repositories[repoType]}/${baseImageName}:${tag}"
}

def getRegistryConfig(repoType) {
    def configs = [
        'internal': ['https://<ВАШ_REGISTRY_URL>/', '<ID_УЧЕТНЫХ_ДАННЫХ_REGISTRY_INTERNAL>'],
        'public': ['https://<ВАШ_REGISTRY_URL>/', '<ID_УЧЕТНЫХ_ДАННЫХ_REGISTRY_PUBLIC>'],
        'docker-hub': ['https://registry.hub.docker.com', '<ID_УЧЕТНЫХ_ДАННЫХ_DOCKERHUB>']
    ]
    return configs[repoType]
}

Шаблон пайплайна для Бэкенда (Platform)

Note

Этот пайплайн ориентирован на .NET-приложение. Он включает этап статического анализа кода с использованием SonarQube внутри Docker-контейнера SDK

pipeline {
    agent any     
    environment {
        SONAR_TOKEN = credentials('<ВАШ_ID_УЧЕТНЫХ_ДАННЫХ_SONAR>')
        IMAGE_NAME = 'ispace.platform'
    }    
    options {
        timestamps()
    }    
    parameters {
        string(name: 'TAG', defaultValue: 'latest', description: 'Введите версию (TAG) для образа')
        choice(name: 'BRANCH', choices: ['develop', 'main', 'release/x.x.x'], description: 'Выберите целевую ветку для сборки')
        choice(name: 'NEXUS_REPO', choices: ['internal', 'public', 'docker-hub'], description: 'Выберите целевой репозиторий для публикации')
    }

    stages {

        stage('CleanUp') { 
            steps {
                echo "--- START CLEANUP STAGE ---" 
                cleanWs notFailBuild: true
                echo "--- END CLEANUP STAGE ---" 
            }
        }

        stage('Git Checkout') { 
            steps {
                echo "--- START GIT CHECKOUT ---"
                echo "Checking out branch: ${params.BRANCH}"
                checkout scm: [
                    $class: 'GitSCM', 
                    branches: [[name: "*/${params.BRANCH}"]], 
                    extensions: [], 
                    userRemoteConfigs: [[
                        credentialsId: '<ВАШ_ID_УЧЕТНЫХ_ДАННЫХ_GIT>', 
                        url: 'https://<ВАШ_GIT_SERVER>/<ВАШ_ПРОЕКТ>/ispace.platform.git'
                    ]]
                ]
                echo "--- END GIT CHECKOUT ---"
            }
        }

        stage('SonarQube analysis') {
            when {
                not { expression { return params.BRANCH == 'main' } }
            }  
            steps {
                echo "--- START SonarQube Analysis (.NET in Docker) ---"
                script {
                    // Запуск анализа внутри контейнера с .NET SDK 
                    docker.image('mcr.microsoft.com/dotnet/sdk:8.0').inside {
                        sh """
                            export HOME=/tmp
                            export DOTNET_CLI_HOME=/tmp                            
                            # Установка сканера SonarQube для .NET
                            dotnet tool install --global dotnet-sonarscanner
                            export PATH="\$PATH:/tmp/.dotnet/tools"                            
                            # Начало анализа
                            dotnet sonarscanner begin \
                                -k:"iSpace.Platform" \
                                -d:sonar.host.url="<ВАШ_URL_SONARQUBE>" \
                                -d:sonar.token="${SONAR_TOKEN}" \
                                -d:sonar.cs.opencover.reportsPaths="**/*.opencover.xml"
                            dotnet build ./iSpacePlatform.slnx -c RELEASE                            
                            # Завершение анализа
                            dotnet sonarscanner end -d:sonar.token="${SONAR_TOKEN}"
                        """
                    }
                }
                echo "--- END SonarQube Analysis ---"
            }
        }

        stage('Build Docker Image') {
            steps {
                echo "--- START Docker build iSpace.Platform ---"
                script {
                    def fullImageName = getImageName(params.NEXUS_REPO, env.IMAGE_NAME, params.TAG)
                    echo "Building image: ${fullImageName}"                    
                    // Укажите правильный путь к Dockerfile бэкенда
                    docker.build("${fullImageName}", "-f Conteq.iSpace.WebApi/Dockerfile.dockerfile .")
                }
                echo "--- END Docker build iSpace.Platform ---"
            }
        }

        stage('Push to Selected Repository') {
            steps {
                echo "--- START Docker push to ${params.NEXUS_REPO} ---"
                script {
                    def fullImageName = getImageName(params.NEXUS_REPO, env.IMAGE_NAME, params.TAG)
                    def (registryUrl, credentialsId) = getRegistryConfig(params.NEXUS_REPO)

                    docker.withRegistry(registryUrl, credentialsId) {
                        def dockerImage = docker.image(fullImageName)
                        dockerImage.push() 
                    }
                }
                echo "--- END Docker push ---"                
            }
        }
    }

    post {
        success {
            echo 'Pipeline completed successfully'
        }
        failure {
            echo 'Pipeline failed'
            mail to: '<ВАШ_EMAIL_ДЛЯ_УВЕДОМЛЕНИЙ>@company.com',
                subject: "Jenkins Pipeline Failed: ${env.JOB_NAME} ${env.BUILD_NUMBER}",
                body: "The build ${env.BUILD_NUMBER} of ${env.JOB_NAME} has failed. Please check Jenkins for more details."
        }
    }
}

// 📍 ВСПОМОГАТЕЛЬНЫЕ ФУНКЦИИ (аналогичны фронтенду)
def getImageName(repoType, baseImageName, tag) {
    def repositories = [
        'internal': '<ВАШ_REGISTRY_URL>/internal',
        'public': '<ВАШ_REGISTRY_URL>/public', 
        'docker-hub': '<ВАШ_DOCKERHUB_ORG>' 
    ]
    return "${repositories[repoType]}/${baseImageName}:${tag}"
}

def getRegistryConfig(repoType) {
    def configs = [
        'internal': ['https://<ВАШ_REGISTRY_URL>/', '<ID_УЧЕТНЫХ_ДАННЫХ_REGISTRY_INTERNAL>'],
        'public': ['https://<ВАШ_REGISTRY_URL>/', '<ID_УЧЕТНЫХ_ДАННЫХ_REGISTRY_PUBLIC>'],
        'docker-hub': ['https://registry.hub.docker.com', '<ID_УЧЕТНЫХ_ДАННЫХ_DOCKERHUB>']
    ]
    return configs[repoType]
}

Note

Чтобы пайплайны успешно выполнялись в вашем окружении, обязательно проверьте и измените следующие параметры:

  • URL репозиториев: Замените https://<ВАШ_GIT_SERVER>/... на реальные адреса ваших репозиториев в GitLab, Bitbucket или другом Git-сервере.

  • Идентификаторы учетных данных (Credentials ID): В Jenkins создайте записи для Git, Docker Registry и SonarQube. Вставьте их ID (например, git-creds-id) вместо заглушек <ВАШ_ID_УЧЕТНЫХ_ДАННЫХ_...>.